glo.tol de iForense

glossary, vocabulary, functions.

Declaraciones

Constantes

Text GloAll
Table with all the glossary, terms and their definitions.
Text GloLow
All the glossary in lower case for test keywords.
Set GloMem
Set with the memory of all terms writed.
Text GloTop
Top terms of the glossary. Is a text for use in posts when no other terms are defined.
Set GloDef
Default terms of the glossary to avoid doubles definitions. For internal use in this library.

Funciones

Text GloFind(Text trmTxt)
Retorna para un termino el mismo termino y su definicion. La busqueda la realiza de forma exacta con sus mayusculas y minusculas. Retorna la tira vacia si no la encuentra emitiendo un mensaje de error.
Real GloTest(Set trmKey)
Prueba un conjunto de palabras clave para ver si aparecen como terminos del glosario y visualiza las que pudieran serlo. Retorna el numero de palabras cadidatas.
Text GloQuote(Text trmTxt)
Retorna para un termino el mismo termino y su definicion como un parrafo Html de tipo blockquote. La busqueda la realiza de forma exacta con sus mayusculas y minusculas. Retorna la tira vacia si no encuentra la definicion.
Text GloRand(Text trmLst)
Retorna para un termino, elegido al azar de entre una lista de terminos, el mismo termino y su definicion como un parrafo Html de tipo blockquote. La busqueda la realiza de forma exacta con sus mayusculas y minusculas. Retorna la tira vacia si no encuentra la definicion.
Real GloStats(Real numMin)
Retorna el numero de terminos con igual o mas numMin ocurrencias y como efecto lateral los visualiza.

Constantes

Text GloAll

//////////////////////////////////////////////////////////////////////////////
Text GloAll = ReadFile("../../agenda/20.glosario.all");
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Table with all the glossary, terms and their definitions.",
GloAll);
//////////////////////////////////////////////////////////////////////////////

Text GloLow

//////////////////////////////////////////////////////////////////////////////
Text GloLow = ToLower(GloAll);
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"All the glossary in lower case for test keywords.",
GloLow);
//////////////////////////////////////////////////////////////////////////////

Set GloMem

//////////////////////////////////////////////////////////////////////////////
Set GloMem = Copy(Empty);
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Set with the memory of all terms writed.",
GloMem);
//////////////////////////////////////////////////////////////////////////////

Text GloTop

//////////////////////////////////////////////////////////////////////////////
Text GloTop = "En vivo|Informática forense|Escenario forense digital|"+
              "Perito informático|Perito judicial|Perito|Post-mortem|"+
              "Cadena de custodia|Ciencia forense|Prueba digital|Prueba";
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Top terms of the glossary. Is a text for use in posts when no other terms
are defined.",
GloTop);
//////////////////////////////////////////////////////////////////////////////

Set GloDef

//////////////////////////////////////////////////////////////////////////////
Set GloDef = Unique(Txt2Set(

// 2 Bibliografía sobre informática forense y pericial
  "Black Hat|CSO|NCJRS|"+

// 4.2 Entidades citadas
  "ACM|ANSI|cmdLabs|ECCouncil|Honeynet Project|IEEE|ISO|RedIRIS|"+
  "SANS Institute|SWGDE|SWGIT|"+

// 1.1 Herramientas citadas
  "Autopsy Forensic Browser|The Sleuth Kit|"+

// 5 Glosario de informática forense y pericial
  "Abrir una cuenta|Acceso|Actualización|Administrador de web|"+
  "Administrador|Alfanumérico|Anónimo|API|Arc|Bloqueadores de escritura|"+
  "Arranque|ASCII|Autenticación|Binario|BIOS|Arquitectura del computador|"+
  "Bluetooth|Bombardeo de correo electrónico|Botnet|Caballo de Troya|"+
  "Caída del sistema|Ciberespacio|Ciberpunk|Cluster|CMOS|"+
  "Codificación redundante|Codificación|Código corrector|Código detector|"+
  "Código fuente|Compactación de memoria|Confesión judicial|Contraseña|"+
  "Cookie|Copia de seguridad|Correo electrónico spam|Cracker|"+
  "Cuenta de correo electrónico|Cuenta de usuario|Demandado|"+
  "Denegación de servicio|Densidad de grabación|Desbordamiento|Descargar|"+
  "Dirección de correo electrónico|Dominio|Esculpido de fichero|Ética|"+
  "Excepción|Exploit|Fichero comprimido|Firma digital|Firma electrónica|"+
  "Firmware|Formatear|Gusano|Hacker|Hashing|Hiperenlace|"+
  "Hipertexto|Hipótesis|Honeypot|Host|HTML|HTTP|Identificador de usuario|"+
  "Inodo|Insaculación|Interbloqueo|Interdicción|Juramento|Keylogger|"+
  "Login|Logout|Lugar del hallazgo|Mainframe|Máscara|Mensaje|Micronúcleo|"+
  "MIME|Modo privilegiado|Moral|Motor de búsqueda|Navegador|"+
  "Nombre de usuario|Núcleo de un sistema operativo|Página de web|Parche|"+
  "Partición|Periférico|Personalizar|Phishing|Pila|Pirata informático|"+
  "Piratería informática|Pista|Pornografía ilegal|Pornografía infantil|"+
  "Pornografía|Procesador|Proceso|Programa ejecutable|Programa fuente|"+
  "Programa objeto|Programa|Programación|Programador|Promesa|"+
  "Prueba|Prueba testifical|Puerta trasera|Puerto|RAM|Recoger|Red social|"+
  "Residente|Respuesta a incidentes|ROM|Rootkit|Script|SCSI|"+
  "Sector de arranque|Sector|Seguridad de la información|"+
  "Seguridad del sistema|Seguridad del software|Seguridad informática|"+
  "Sistema informático|Software malicioso|SQL|"+
  "Tecnología de la información|Terminal|Transductor|URL|Virus|Volcado|"+
  "Web crawler", "|"));
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Default terms of the glossary to avoid doubles definitions.
For internal use in this library.",
GloDef);
//////////////////////////////////////////////////////////////////////////////

Funciones

Text GloFind()

//////////////////////////////////////////////////////////////////////////////
Text GloFind(Text trmTxt) // Term
//////////////////////////////////////////////////////////////////////////////
{
  Text trmTag = "["+trmTxt+"]: ";
  Text trmFnd = TxtBetween2Tag(GloAll, "\n> "+trmTag, "\n", FALSE);
  If(trmFnd != "",
  {
    Text trmRep = ReplaceTable(trmTag+trmFnd, [[ [["[", "<b>" ]],
                                                 [["]", "</b>"]] ]]);

    Text urlTxt = TxtBetween2Tag(trmRep+"|", "| Url: ", "|", FALSE);

    Case(
      urlTxt=="", trmRep, // No hay Urls / no publicar urls de la wikipedia
      TextFind(urlTxt,"wikipedia"), Replace(trmRep, "| Url: "+urlTxt, ""),
      TRUE,
      {
        Set  urlSet = Tokenizer(urlTxt, "*"); // Urls puede haber varias con *
        Set  urlSel = Select(urlSet, Real(Text url)  { Compact(url)!="" });
        Set  urlTab = EvalSet(urlSel, Set(Text url)
        {
          Text urlCmp = Compact(url);
               // Una mayuscula para evitar cambios en urls cuando se parecen
          Text urlLnk = "<a href="+Q(FirstToUpper(urlCmp))+">"+urlCmp+"</a>";
          SetOfText(urlCmp, urlLnk)
        });  
/*      Set  srtTab = Sort(urlTab, Real(Set a, Set b)
                      { Compare(TextLength(b[1]),TextLength(a[1])) });
                      // Cambiar las Url más largas las primeras
                      Text WriteLn(F(srtTab));
        TxtReplaceSecuence(trmRep, srtTab) // Convierte Urls en links */
        TxtReplaceSecuence(trmRep, urlTab) // Convierte Urls en links
      })
  },
  {
    Text WriteLn("\nERROR "+trmTag+" not found in the glossary.\n");
    ""
  })
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna para un termino el mismo termino y su definicion.
La busqueda la realiza de forma exacta con sus mayusculas y minusculas.
Retorna la tira vacia si no la encuentra emitiendo un mensaje de error.",
GloFind);
//////////////////////////////////////////////////////////////////////////////

Real GloTest()

//////////////////////////////////////////////////////////////////////////////
Real GloTest(Set trmKey) // Set of terms from keywords, lowercase all
//////////////////////////////////////////////////////////////////////////////
{
  Text Write("Glossary: ");
  Set cicTst = EvalSet(trmKey, Real(Text trmTxt)
  {
    Text trmTag = "> ["+trmTxt; // Solo el inicio
    If(!TextFind(GloLow, trmTag), 0,
       { Text Write(FirstToUpper(trmTxt)+"|"); 1 })
  });
  Text WriteLn("\n");
  SetSum(cicTst)
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Prueba un conjunto de palabras clave para ver si aparecen como terminos
del glosario y visualiza las que pudieran serlo.
Retorna el numero de palabras cadidatas.",
GloTest);
//////////////////////////////////////////////////////////////////////////////

Text GloQuote()

//////////////////////////////////////////////////////////////////////////////
Text GloQuote(Text trmTxt) // Term
//////////////////////////////////////////////////////////////////////////////
{
  Text trmDef = GloFind(trmTxt);
  If(trmDef == "", "", // Not found
     "<blockquote><p>"+trmDef+"</p></blockquote>")
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna para un termino el mismo termino y su definicion como un parrafo
Html de tipo blockquote.
La busqueda la realiza de forma exacta con sus mayusculas y minusculas.
Retorna la tira vacia si no encuentra la definicion.",
GloQuote);
//////////////////////////////////////////////////////////////////////////////

Text GloRand()

//////////////////////////////////////////////////////////////////////////////
Text GloRand(Text trmLst) // List of texts separated with |
//////////////////////////////////////////////////////////////////////////////
{
  Set trmSet = Unique(Txt2Set(trmLst, "|")); // Todos los terminos
  Set trmNew = trmSet - GloMem; // Los no utilizados
  
  // Lo nuevos si quedan y si no los por defecto
  Set trmUse = If(Card(trmNew), trmNew,
  {
    Set trmLef = GloDef - GloMem; // Los por defecto no utilizados
    If(Card(trmLef), trmLef, GloDef) // Si se han usado todos -> repite
  });

  Text trmTxt = SetGetRand(trmUse); // Uno al azar
  Set(GloMem := Copy(GloMem << SetOfText(trmTxt)));

  GloQuote(trmTxt)
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna para un termino, elegido al azar de entre una lista de terminos,
el mismo termino y su definicion como un parrafo Html de tipo blockquote.
La busqueda la realiza de forma exacta con sus mayusculas y minusculas.
Retorna la tira vacia si no encuentra la definicion.",
GloRand);
//////////////////////////////////////////////////////////////////////////////

Real GloStats()

//////////////////////////////////////////////////////////////////////////////
Real GloStats(Real numMin) // Escribe los terminos con >= numMin ocurrencias
//////////////////////////////////////////////////////////////////////////////
{
  // Cuenta ocurrencias
  Set  gloCla = Classify(GloMem, Real(Text a, Text b)
       { Compare(a,b) });

  // Selecciona las que tengan igual o mas de numMin ocurrencias
  Set  gloSel = Select(gloCla, Real(Set a)
       { GE(Card(a), numMin) });

  // Ordena de mas a menos ocurrencias
  Set  gloSrt = Sort(gloSel, Real(Set a, Set b)
       { Compare(Card(b), Card(a)) });

  // Visualiza
  Text WriteLn("");
  Set  gloWri = EvalSet(gloSrt, Real(Set a)
  {
    Text WriteLn(FormatReal(Card(a), "%3.0lf")+" "+a[1]);
    TRUE
  });
  
  Card(gloWri)
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna el numero de terminos con igual o mas numMin ocurrencias y como
efecto lateral los visualiza.",
GloStats);
//////////////////////////////////////////////////////////////////////////////

Time oriented language

//////////////////////////////////////////////////////////////////////////////
// FILE    : glo.tol
// AUTHOR  : http://www.asolver.com
// PURPOSE : glossary, vocabulary, functions.
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
// CONSTANTS
//////////////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////////////
Text GloAll = ReadFile("../../agenda/20.glosario.all");
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Table with all the glossary, terms and their definitions.",
GloAll);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Text GloLow = ToLower(GloAll);
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"All the glossary in lower case for test keywords.",
GloLow);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Set GloMem = Copy(Empty);
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Set with the memory of all terms writed.",
GloMem);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Text GloTop = "En vivo|Informática forense|Escenario forense digital|"+
              "Perito informático|Perito judicial|Perito|Post-mortem|"+
              "Cadena de custodia|Ciencia forense|Prueba digital|Prueba";
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Top terms of the glossary. Is a text for use in posts when no other terms
are defined.",
GloTop);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Set GloDef = Unique(Txt2Set(

// 2 Bibliografía sobre informática forense y pericial
  "Black Hat|CSO|NCJRS|"+

// 4.2 Entidades citadas
  "ACM|ANSI|cmdLabs|ECCouncil|Honeynet Project|IEEE|ISO|RedIRIS|"+
  "SANS Institute|SWGDE|SWGIT|"+

// 1.1 Herramientas citadas
  "Autopsy Forensic Browser|The Sleuth Kit|"+

// 5 Glosario de informática forense y pericial
  "Abrir una cuenta|Acceso|Actualización|Administrador de web|"+
  "Administrador|Alfanumérico|Anónimo|API|Arc|Bloqueadores de escritura|"+
  "Arranque|ASCII|Autenticación|Binario|BIOS|Arquitectura del computador|"+
  "Bluetooth|Bombardeo de correo electrónico|Botnet|Caballo de Troya|"+
  "Caída del sistema|Ciberespacio|Ciberpunk|Cluster|CMOS|"+
  "Codificación redundante|Codificación|Código corrector|Código detector|"+
  "Código fuente|Compactación de memoria|Confesión judicial|Contraseña|"+
  "Cookie|Copia de seguridad|Correo electrónico spam|Cracker|"+
  "Cuenta de correo electrónico|Cuenta de usuario|Demandado|"+
  "Denegación de servicio|Densidad de grabación|Desbordamiento|Descargar|"+
  "Dirección de correo electrónico|Dominio|Esculpido de fichero|Ética|"+
  "Excepción|Exploit|Fichero comprimido|Firma digital|Firma electrónica|"+
  "Firmware|Formatear|Gusano|Hacker|Hashing|Hiperenlace|"+
  "Hipertexto|Hipótesis|Honeypot|Host|HTML|HTTP|Identificador de usuario|"+
  "Inodo|Insaculación|Interbloqueo|Interdicción|Juramento|Keylogger|"+
  "Login|Logout|Lugar del hallazgo|Mainframe|Máscara|Mensaje|Micronúcleo|"+
  "MIME|Modo privilegiado|Moral|Motor de búsqueda|Navegador|"+
  "Nombre de usuario|Núcleo de un sistema operativo|Página de web|Parche|"+
  "Partición|Periférico|Personalizar|Phishing|Pila|Pirata informático|"+
  "Piratería informática|Pista|Pornografía ilegal|Pornografía infantil|"+
  "Pornografía|Procesador|Proceso|Programa ejecutable|Programa fuente|"+
  "Programa objeto|Programa|Programación|Programador|Promesa|"+
  "Prueba|Prueba testifical|Puerta trasera|Puerto|RAM|Recoger|Red social|"+
  "Residente|Respuesta a incidentes|ROM|Rootkit|Script|SCSI|"+
  "Sector de arranque|Sector|Seguridad de la información|"+
  "Seguridad del sistema|Seguridad del software|Seguridad informática|"+
  "Sistema informático|Software malicioso|SQL|"+
  "Tecnología de la información|Terminal|Transductor|URL|Virus|Volcado|"+
  "Web crawler", "|"));
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Default terms of the glossary to avoid doubles definitions.
For internal use in this library.",
GloDef);
//////////////////////////////////////////////////////////////////////////////




//////////////////////////////////////////////////////////////////////////////
// FUNCTIONS
//////////////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////////////
Text GloFind(Text trmTxt) // Term
//////////////////////////////////////////////////////////////////////////////
{
  Text trmTag = "["+trmTxt+"]: ";
  Text trmFnd = TxtBetween2Tag(GloAll, "\n> "+trmTag, "\n", FALSE);
  If(trmFnd != "",
  {
    Text trmRep = ReplaceTable(trmTag+trmFnd, [[ [["[", "<b>" ]],
                                                 [["]", "</b>"]] ]]);

    Text urlTxt = TxtBetween2Tag(trmRep+"|", "| Url: ", "|", FALSE);

    Case(
      urlTxt=="", trmRep, // No hay Urls / no publicar urls de la wikipedia
      TextFind(urlTxt,"wikipedia"), Replace(trmRep, "| Url: "+urlTxt, ""),
      TRUE,
      {
        Set  urlSet = Tokenizer(urlTxt, "*"); // Urls puede haber varias con *
        Set  urlSel = Select(urlSet, Real(Text url)  { Compact(url)!="" });
        Set  urlTab = EvalSet(urlSel, Set(Text url)
        {
          Text urlCmp = Compact(url);
               // Una mayuscula para evitar cambios en urls cuando se parecen
          Text urlLnk = "<a href="+Q(FirstToUpper(urlCmp))+">"+urlCmp+"</a>";
          SetOfText(urlCmp, urlLnk)
        });  
/*      Set  srtTab = Sort(urlTab, Real(Set a, Set b)
                      { Compare(TextLength(b[1]),TextLength(a[1])) });
                      // Cambiar las Url más largas las primeras
                      Text WriteLn(F(srtTab));
        TxtReplaceSecuence(trmRep, srtTab) // Convierte Urls en links */
        TxtReplaceSecuence(trmRep, urlTab) // Convierte Urls en links
      })
  },
  {
    Text WriteLn("\nERROR "+trmTag+" not found in the glossary.\n");
    ""
  })
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna para un termino el mismo termino y su definicion.
La busqueda la realiza de forma exacta con sus mayusculas y minusculas.
Retorna la tira vacia si no la encuentra emitiendo un mensaje de error.",
GloFind);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Real GloTest(Set trmKey) // Set of terms from keywords, lowercase all
//////////////////////////////////////////////////////////////////////////////
{
  Text Write("Glossary: ");
  Set cicTst = EvalSet(trmKey, Real(Text trmTxt)
  {
    Text trmTag = "> ["+trmTxt; // Solo el inicio
    If(!TextFind(GloLow, trmTag), 0,
       { Text Write(FirstToUpper(trmTxt)+"|"); 1 })
  });
  Text WriteLn("\n");
  SetSum(cicTst)
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Prueba un conjunto de palabras clave para ver si aparecen como terminos
del glosario y visualiza las que pudieran serlo.
Retorna el numero de palabras cadidatas.",
GloTest);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Text GloQuote(Text trmTxt) // Term
//////////////////////////////////////////////////////////////////////////////
{
  Text trmDef = GloFind(trmTxt);
  If(trmDef == "", "", // Not found
     "<blockquote><p>"+trmDef+"</p></blockquote>")
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna para un termino el mismo termino y su definicion como un parrafo
Html de tipo blockquote.
La busqueda la realiza de forma exacta con sus mayusculas y minusculas.
Retorna la tira vacia si no encuentra la definicion.",
GloQuote);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Text GloRand(Text trmLst) // List of texts separated with |
//////////////////////////////////////////////////////////////////////////////
{
  Set trmSet = Unique(Txt2Set(trmLst, "|")); // Todos los terminos
  Set trmNew = trmSet - GloMem; // Los no utilizados
  
  // Lo nuevos si quedan y si no los por defecto
  Set trmUse = If(Card(trmNew), trmNew,
  {
    Set trmLef = GloDef - GloMem; // Los por defecto no utilizados
    If(Card(trmLef), trmLef, GloDef) // Si se han usado todos -> repite
  });

  Text trmTxt = SetGetRand(trmUse); // Uno al azar
  Set(GloMem := Copy(GloMem << SetOfText(trmTxt)));

  GloQuote(trmTxt)
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna para un termino, elegido al azar de entre una lista de terminos,
el mismo termino y su definicion como un parrafo Html de tipo blockquote.
La busqueda la realiza de forma exacta con sus mayusculas y minusculas.
Retorna la tira vacia si no encuentra la definicion.",
GloRand);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Real GloStats(Real numMin) // Escribe los terminos con >= numMin ocurrencias
//////////////////////////////////////////////////////////////////////////////
{
  // Cuenta ocurrencias
  Set  gloCla = Classify(GloMem, Real(Text a, Text b)
       { Compare(a,b) });

  // Selecciona las que tengan igual o mas de numMin ocurrencias
  Set  gloSel = Select(gloCla, Real(Set a)
       { GE(Card(a), numMin) });

  // Ordena de mas a menos ocurrencias
  Set  gloSrt = Sort(gloSel, Real(Set a, Set b)
       { Compare(Card(b), Card(a)) });

  // Visualiza
  Text WriteLn("");
  Set  gloWri = EvalSet(gloSrt, Real(Set a)
  {
    Text WriteLn(FormatReal(Card(a), "%3.0lf")+" "+a[1]);
    TRUE
  });
  
  Card(gloWri)
};
//////////////////////////////////////////////////////////////////////////////
PutDescription(
"Retorna el numero de terminos con igual o mas numMin ocurrencias y como
efecto lateral los visualiza.",
GloStats);
//////////////////////////////////////////////////////////////////////////////

Árbol de ficheros

iForense construye las paginas del sitio sobre informática forense Forense.Info

←make.tol proceso principal de generacion del sitio web y todas su páginas
tol directorios de código en lenguaje Tol
- cmm funciones comunes
  - ←txt.tol código de funciones de textos
  - ←dte.tol código de funciones de fechas
  - ←set.tol código de funciones de conjuntos
  - ←fil.tol código de funciones de ficheros
  - ←dir.tol código de funciones de directorios
  - ←tme.tol funciones del macro-expansor doble de Tol en Html
  - ←img.tol funciones para imagenes declaradas en Html
  - ←ftp.tol para generar mandatos para hacer Ftp
  - ←xsm.tol para construir sitemaps en Xml
- app funciones específicas de aplicación
  - ←glo.tol de términos del glosario forense e informatico
  - ←pdb.tol de manejo de los posts de una agenda
  - ←pht.tol funciones auxiliares para el Html de los post
- ←inc.tol para la inclusión de ficheros en lenguaje Tol
agenda directorio destinado a la agenda de post
- ←01.presentacion.age ejemplo de los primeros posts del sitio Forense.Info
- ←20.glosario.txt glosario de ejemplo con algunos términos de informática forense
web directorio destinado a las páginas web generadas y a contenido
- css directorio para ficheros de estilo de tipo Css
  - ←common.css fichero Cascading Style Sheets para las paginas Html
- seed directorio para ficheros semilla
  - ←seed.htm semilla de página Html, template, con Tol embebido
- src directorio para ficheros con código Javascript
  - ←common.js funciones Javascript de redes sociales y multimedia
- imagenes directorio de ilustraciones del sitio web
  - ←Perito.cpb.CrackingPasswordsFuerzaBruta.png ejemplo de imagen ilustrativa de Forense.Info
  - ←Perito.pmm.MapaModulo.png ejemplo de esquema ilustrativo de Forense.Info
- articulos directorio para las páginas de artículos de informática forense
  - →peritojudicial.html ejemplo de página Html de artículo generada
- categorias directorio para paginas de categorias de informática forense
  - →presentacion.html ejemplo de página Html de categoría generada
- →sitemap.xml mapa del sitio web generado automáticamente en Xml
→resultado.html muestra del web de informática forense del dominio Forense.Info
→iforense.pdf documento resumen de funciones del programa creador del web

Secciones de la página

Funciones

Artículos del sitio

Por categorías

glo.tol de iForense

Declaraciones

Constantes

Text GloAll

Text GloLow

Set GloMem

Text GloTop

Set GloDef

Funciones

Text GloFind()

Real GloTest()

Text GloQuote()

Text GloRand()

Real GloStats()

Time oriented language

Árbol de ficheros